COMMENT ⊗   VALID 00005 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00002 00002	% Special characters for ``extended ASCII character set'' fonts
C00004 00003	cmchar "Blank space"
C00005 00004	cmchar "Circumflex (hat) accent"
C00007 00005	cmchar "Tilde (squiggle) accent"
C00009 ENDMK
C⊗;
% Special characters for ``extended ASCII character set'' fonts

% Two accents have been copied from {\tt accent.mf}
% and there's also a (genuinely) blank space.

% Codes \0040, \0136, and \0176 are generated, in addition to the following:
cdot=oct"000";
down_arrow=oct"001";
meet=oct"004";
false_that=oct"005";
elt=oct"006";
up_arrow=oct"013";
plus_minus=oct"014";
o_plus=oct"015";
infty=oct"016";
subset=oct"020";
superset=oct"021";
cap=oct"022";
cup=oct"023";
for_all=oct"024";
there_exists=oct"025";
o_times=oct"026";
double_arrow=oct"027";
left_arrow=oct"030";
right_arrow=oct"031";
neq=oct"032";
diamond=oct"033";
leq=oct"034";
geq=oct"035";
eqv=oct"036";
join=oct"037";
straight_quotes=oct"042";
minus=oct"055";
less=oct"074";
greater=oct"076";
backslash=oct"134";
underbar=oct"137";
left_brace=oct"173";
vertical=oct"174";
right_brace=oct"175";
integral=oct"177";

input sym
cmchar "Blank space";
beginchar(oct"040",6u#,0,0);
adjust_fit(0,0); endchar;
cmchar "Circumflex (hat) accent";
beginchar(oct"136",9u#,min(asc_height#,2x_height#),0); less_rounded;
if serifs: italcorr .5[x_height#,h#]*slant+.5hair#-1.75u#;
 adjust_fit(0,0);
 pickup crisp.nib; pos2(.5[vair,curve],90); top y2r=h; x2=.5w;
 x1=w-x3=2.25u; y1=y3=.5[x_height,y2];
 pos1(hair,angle(z2-z1)+90); pos3(hair,angle(z3-z2)+90);
 filldraw stroke z1e--z2e--z3e;	% diagonals
else: italcorr 2/3[x_height#,h#]*slant-.5stem#+.5vair#-.75u#;
 adjust_fit(0,0);
 pickup fine.nib; pos1(vair,0); pos3(vair,0); x1=w-x3;
 pos2(stem,0); top y2=h; x2=.5w; bot y1=bot y3=round(2/3[h,x_height]);
 lft x1l=round(rt x2r-3.25u-.5vair); % same slope as in the acute accent
 z0=whatever[z1r,z2r]=whatever[z2l,z3l];
 y4l=y4r=y2; x4l=good.x(.2[x2l,x2]); x4r=w-x4l;
 filldraw z4l--z1l--z1r--z0--z3l--z3r--z4r--cycle; fi	% diagonals
penlabels(0,1,2,3,4); endchar;
cmchar "Tilde (squiggle) accent";
beginchar(oct"176",9u#,min(asc_height#,10/7x_height#+.5dot_size#),0);
italcorr h#*slant-u#;
adjust_fit(0,0);
if serifs: numeric theta; theta=angle(1/6(6u-vair),1/4(h-x_height));
 pickup crisp.nib; numeric mid_width; mid_width=round(.4[vair,stem]);
 pos1(vair,theta+90); pos2(vair,theta+90);
 pos3(vair,theta+90); pos4(vair,theta+90);
 z2-z1=z4-z3=(mid_width-crisp)*dir theta;
 lft x1r=w-rt x4l=round 1.5u; top y4r=h;
 bot y1l=round(bot y1l+min(2/3[x_height,h],y3l-.25vair)-top y1r);
 pair delta; ypart delta=3(y3l-y1l); delta=whatever*dir theta;
 filldraw z1l..controls(z1l+delta)and(z3l-delta)..z3l..z4l
  --z4r..controls(z4r-delta)and(z2r+delta)..z2r..z1r--cycle;	% stroke
else: pickup fine.nib; pos1(vair,180); pos2(vair,90);
 pos3(.5[vair,slab],90); pos4(vair,90); pos5(vair,180);
 lft x1r=w-rt x5l=round 1.5u; x2-x1=x3-x2=x4-x3=x5-x4;
 bot y1=bot y4l=round(.75[x_height,h]-vair); top y2r=top y5=h; y3=.5[y2,y4];
 filldraw stroke z1e{up}...z2e{right}..z3e..{right}z4e...{up}z5e; fi % stroke
penlabels(1,2,3,4,5); endchar;